qt/LedOK/LedOK Express.pro

QT += core gui widgets
QT += multimedia
QT += network
QT += concurrent
QT += serialport
QT += opengl
QT += webenginewidgets

greaterThan(QT_MAJOR_VERSION, 5) {
    QT += openglwidgets
    CONFIG += c++20
} else {
    CONFIG += c++17
    QMAKE_CFLAGS += /utf-8
    QMAKE_CXXFLAGS += /utf-8
}

CONFIG += lrelease
CONFIG += embed_translations

# CONFIG += console

# You can also make your code fail to compile if you use deprecated APIs.
# In order to do so, uncomment the following line.
# You can also select to disable deprecated APIs only up to a certain version of Qt.
#DEFINES += QT_DISABLE_DEPRECATED_BEFORE=0x060000    # disables all the APIs deprecated before Qt 6.0.0

VERSION = 1.5.1
DEFINES += APP_VERSION=\\\"$$VERSION\\\"
msvc {
    contains(QT_ARCH, i386) {
        QMAKE_LFLAGS += /LARGEADDRESSAWARE
    }
    CONFIG += force_debug_info
    CONFIG += separate_debug_info
}
win32 {
    CONFIG -= debug_and_release
    LIBS += -lwinmm
    LIBS += -lDbghelp

    RC_ICONS = res/Logo.ico
}
osx {
    QMAKE_MACOSX_DEPLOYMENT_TARGET = 11.0
    -mmacosx-version-min=11.0
    ICON = res/Logo-raw.png
}


copydir.files += AClock
copydir.files += borders
copydir.files += Demos
copydir.files += translations
copydir.files += rk_lcd_parameters
copydir.files += $$quote(files)

win32 {
    EXE_SUFFIX = .exe
    contains(QT_ARCH, i386) {
        DIR_SUFFIX = -32
        copy.files += $$files(OpenSSL/*.dll)  # for https requests
    }

    copy.files += $$files(ffmpeg$$DIR_SUFFIX/bin/*.dll)
    copy.files += 7z/7z.dll
    copy.files += 7z/7z.exe

    copy.path = $$OUT_PWD
    copydir.path = $$OUT_PWD
    CONFIG += file_copies
    COPIES += copy
    COPIES += copydir
}
osx {
    DIR_SUFFIX = -mac

    copy.path = Contents/MacOS
    copydir.path = Contents/MacOS
    QMAKE_BUNDLE_DATA += copy
    QMAKE_BUNDLE_DATA += copydir
}
copy.files += ffmpeg$$DIR_SUFFIX/bin/ffmpeg$$EXE_SUFFIX

INCLUDEPATH += $$PWD/ffmpeg$$DIR_SUFFIX/include
LIBS += -L$$PWD/ffmpeg$$DIR_SUFFIX/lib/\
        -lavcodec \
        -lavdevice \
        -lavfilter \
        -lavformat \
        -lavutil \
        -lswresample \
        -lswscale

# Default rules for deployment.
qnx: target.path = /tmp/$${TARGET}/bin
else: unix:!android: target.path = /opt/$${TARGET}/bin
!isEmpty(target.path): INSTALLS += target

RESOURCES += res.qrc

SOURCES += \
    base/changepasswordform.cpp \
    base/switchcontrol.cpp \
    base/extendedgroupbox.cpp \
    base/ffutil.cpp \
    base/locolorselector.cpp \
    base/lodateselector.cpp \
    base/loqtitlebar.cpp \
    base/loqtreewidget.cpp \
    gutil/qcore.cpp \
    gutil/qwaitingdlg.cpp \
    basedlg.cpp \
    basewin.cpp \
    cfg.cpp \
    device/ctrlhdmipanel.cpp \
    device/ctrlnetworkpanel.cpp \
    device/ctrlpowerpanel.cpp \
    device/ctrlpwdpanel.cpp \
    device/ctrltestpanel.cpp \
    device/ctrlvolumepanel.cpp \
    deviceitem.cpp \
    devicepanel.cpp \
    ffplayer.cpp \
    globaldefine.cpp \
    gutil/cpp.cpp \
    gutil/qgui.cpp \
    gutil/qjson.cpp \
    gutil/qnetwork.cpp \
    main.cpp \
    mainwindow.cpp \
    mguangyingpinwidget.cpp \
    player/eleanaclock.cpp \
    player/eleborder.cpp \
    player/eledigiclock.cpp \
    player/elegif.cpp \
    player/elescroll.cpp \
    player/eletimer.cpp \
    player/elevideo.cpp \
    player/playwin.cpp \
    player/posdlg.cpp \
    player/srccopy.cpp \
    progpanel.cpp \
    synctimer.cpp \
    tools.cpp \
    device/ctrladvancedpanel.cpp \
    device/ctrlbrightpanel.cpp \
    device/ctrlverifyclockpanel.cpp \
    device/upgradeapkdialog.cpp \
    program/copydirthread.cpp \
    program/eaclock.cpp \
    program/ebase.cpp \
    program/edclock.cpp \
    program/eenviron.cpp \
    program/egif.cpp \
    program/emultiwin.cpp \
    program/ephoto.cpp \
    program/etext.cpp \
    program/etimer.cpp \
    program/evideo.cpp \
    program/eweb.cpp \
    program/gentmpthread.cpp \
    program/pageeditor.cpp \
    program/pagelistitem.cpp \
    program/progeditorwin.cpp \
    program/progitem.cpp \
    program/sendprogramdialog.cpp \
    program/sendprogthread.cpp \
    program/videosplitthread.cpp

HEADERS += \
    base/changepasswordform.h \
    base/switchcontrol.h \
    base/extendedgroupbox.h \
    base/locolorselector.h \
    base/lodateselector.h \
    base/loqtitlebar.h \
    base/loqtreewidget.h \
    gutil/qcore.h \
    gutil/qwaitingdlg.h \
    basedlg.h \
    basewin.h \
    cfg.h \
    device/ctrlhdmipanel.h \
    device/ctrlnetworkpanel.h \
    device/ctrlpowerpanel.h \
    device/ctrlpwdpanel.h \
    device/ctrltestpanel.h \
    device/ctrlvolumepanel.h \
    deviceitem.h \
    devicepanel.h \
    ffplayer.h \
    globaldefine.h \
    gutil/cpp.h \
    gutil/qgui.h \
    gutil/qjson.h \
    gutil/qnetwork.h \
    mainwindow.h \
    mguangyingpinwidget.h \
    player/eleanaclock.h \
    player/eleborder.h \
    player/eledigiclock.h \
    player/elegif.h \
    player/elescroll.h \
    player/eletimer.h \
    player/elevideo.h \
    player/playwin.h \
    player/posdlg.h \
    player/srccopy.h \
    progpanel.h \
    synctimer.h \
    tools.h \
    device/ctrladvancedpanel.h \
    device/ctrlbrightpanel.h \
    device/ctrlverifyclockpanel.h \
    device/upgradeapkdialog.h \
    program/copydirthread.h \
    program/eaclock.h \
    program/ebase.h \
    program/edclock.h \
    program/eenviron.h \
    program/egif.h \
    program/emultiwin.h \
    program/ephoto.h \
    program/etext.h \
    program/etimer.h \
    program/evideo.h \
    program/eweb.h \
    program/gentmpthread.h \
    program/pageeditor.h \
    program/pagelistitem.h \
    program/progeditorwin.h \
    program/progitem.h \
    program/sendprogramdialog.h \
    program/sendprogthread.h \
    program/videosplitthread.h

TRANSLATIONS += \
    ts/app_zh_CN.ts \
    ts/app_zh_TW.ts \
    ts/app_en.ts \
    ts/app_ja.ts \
    ts/app_pt.ts

include(./xlsx/qtxlsx.pri)