qt/ledset/ledset.pro

QT += core gui widgets
QT += network

CONFIG += c++17
CONFIG += lrelease
CONFIG += embed_translations

# You can make your code fail to compile if it uses deprecated APIs.
# In order to do so, uncomment the following line.
#DEFINES += QT_DISABLE_DEPRECATED_BEFORE=0x060000    # disables all the APIs deprecated before Qt 6.0.0

TARGET = $$quote(LedSet Express)

msvc {
    contains(QT_ARCH, i386) {
        QMAKE_LFLAGS += /LARGEADDRESSAWARE
    }
    lessThan(QT_MAJOR_VERSION, 6) {
        QMAKE_CXXFLAGS += -execution-charset:utf-8
        QMAKE_CXXFLAGS += -source-charset:utf-8
    }
    CONFIG += force_debug_info
    CONFIG += separate_debug_info
}
win32 {
    CONFIG -= debug_and_release
    LIBS += -lDbghelp

    RC_ICONS = 128.ico
}

INCLUDEPATH += $$PWD/npcap-sdk-1.13/Include
LIBS += -L$$PWD/npcap-sdk-1.13/Lib/\
        -lwpcap\
        -lpacket

RESOURCES += res.qrc

SOURCES += \
    basewin.cpp \
    brightwin.cpp \
    crc.c \
    expertboxlayoutwin.cpp \
    expertscreenconnwin.cpp \
    expertsmartpointsetwin.cpp \
    expertwin.cpp \
    fast.cpp \
    globalfunc.cpp \
    gutil/qgui.cpp \
    main.cpp \
    mainwin.cpp \
    moduleunit.cpp \
    pcaprethread.cpp \
    screenunit.cpp \
    testwin.cpp \
    videowin.cpp \
    waitingdlg.cpp

HEADERS += \
    basewin.h \
    brightwin.h \
    crc.h \
    expertboxlayoutwin.h \
    expertscreenconnwin.h \
    expertsmartpointsetwin.h \
    expertwin.h \
    fast.h \
    globalfunc.h \
    gutil/qgui.h \
    mainwin.h \
    moduleunit.h \
    pcaprethread.h \
    screenunit.h \
    testwin.h \
    videowin.h \
    waitingdlg.h

TRANSLATIONS += \
    translations/app_en.ts

EXTRA_TRANSLATIONS += \
    translations/qt_zh_CN.ts \
    translations/qt_zh_TW.ts \
    translations/qt_ja.ts \
    translations/qt_en.ts



# Default rules for deployment.
qnx: target.path = /tmp/$${TARGET}/bin
else: unix:!android: target.path = /opt/$${TARGET}/bin
!isEmpty(target.path): INSTALLS += target