qt/ledset/ledset.pro

QT += core gui widgets
QT += network

CONFIG += c++17
CONFIG += lrelease
CONFIG += embed_translations

# You can make your code fail to compile if it uses deprecated APIs.
# In order to do so, uncomment the following line.
#DEFINES += QT_DISABLE_DEPRECATED_BEFORE=0x060000    # disables all the APIs deprecated before Qt 6.0.0

TARGET = $$quote(LedSet Express)
DEFINES += __VER__=\\\"0.0.1\\\"

msvc {
    contains(QT_ARCH, i386) {
        QMAKE_LFLAGS += /LARGEADDRESSAWARE
    }
    lessThan(QT_MAJOR_VERSION, 6) {
        QMAKE_CXXFLAGS += -execution-charset:utf-8
        QMAKE_CXXFLAGS += -source-charset:utf-8
    }
    CONFIG += force_debug_info
    CONFIG += separate_debug_info
}
win32 {
    CONFIG -= debug_and_release
    LIBS += -lDbghelp

    RC_ICONS = 128.ico
}


copydir.files += translations
copy.files += $$files(files/*.ic)

win32 {
    EXE_SUFFIX = .exe
    copy.path = $$OUT_PWD
    copydir.path = $$OUT_PWD
    CONFIG += file_copies
    COPIES += copy
    COPIES += copydir
}
osx {
    DIR_SUFFIX = -mac
    copydir.path = Contents/MacOS
    QMAKE_BUNDLE_DATA += copydir
}


INCLUDEPATH += $$PWD/npcap-sdk-1.13/Include
LIBS += -L$$PWD/npcap-sdk-1.13/Lib/\
        -lwpcap\
        -lpacket

LIBS += -L$$PWD -lefffrefr

RESOURCES += res.qrc

SOURCES += \
    basewin.cpp \
    brightwin.cpp \
    crc.c \
    expertboxlayoutwin.cpp \
    expertscreenconnwin.cpp \
    expertsendpanel.cpp \
    expertsmartpointsetwin.cpp \
    expertwin.cpp \
    fast.cpp \
    globalfunc.cpp \
    gutil/cu.cpp \
    gutil/qgui.cpp \
    gutil/qjson.cpp \
    ic_ui/doublelatcheffectwin.cpp \
    ic_ui/icn2053.cpp \
    ic_ui/normaleffectwin.cpp \
    ic_ui/pwmeffectwin.cpp \
    main.cpp \
    mainwin.cpp \
    pcaprethread.cpp \
    testwin.cpp \
    videowin.cpp \
    waitingdlg.cpp

HEADERS += \
    basewin.h \
    brightwin.h \
    crc.h \
    efffrefr.h \
    expertboxlayoutwin.h \
    expertscreenconnwin.h \
    expertsendpanel.h \
    expertsmartpointsetwin.h \
    expertwin.h \
    fast.h \
    globalfunc.h \
    gutil/cu.h \
    gutil/qgui.h \
    gutil/qjson.h \
    ic_ui/doublelatcheffectwin.h \
    ic_ui/icn2053.h \
    ic_ui/normaleffectwin.h \
    ic_ui/pwmeffectwin.h \
    mainwin.h \
    pcaprethread.h \
    testwin.h \
    videowin.h \
    waitingdlg.h

TRANSLATIONS += \
    ts/app_en.ts


# Default rules for deployment.
qnx: target.path = /tmp/$${TARGET}/bin
else: unix:!android: target.path = /opt/$${TARGET}/bin
!isEmpty(target.path): INSTALLS += target